smart-bow-infrared/Assets/InfraredProject/Resources/CameraPointsMaskShader.shader

Shader "Custom/CameraPointsMaskShader"
{
    Properties
    {
        _MainTex("Main Texture", 2D) = "white" {}
         // 这里用4个Vector传四个顶点点坐标（UV空间，0~1）
        _QuadP0("Quad Point 0", Vector) = (0,0,0,0)
        _QuadP1("Quad Point 1", Vector) = (0,0,0,0)
        _QuadP2("Quad Point 2", Vector) = (0,0,0,0)
        _QuadP3("Quad Point 3", Vector) = (0,0,0,0)
    }
        SubShader
    {
        Tags { "RenderType" = "Opaque" }
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            sampler2D _MainTex;
            float4 _QuadP0;
            float4 _QuadP1;
            float4 _QuadP2;
            float4 _QuadP3;

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };

            v2f vert(appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = v.uv;
                return o;
            }

            // 计算2D向量叉积符号
            float sign2D(float2 p1, float2 p2, float2 p3)
            {
                return (p1.x - p3.x) * (p2.y - p3.y) - (p2.x - p3.x) * (p1.y - p3.y);
            }

            // 点是否在四边形内（用两个三角形判定）
            float PointInQuad(float2 p, float2 p0, float2 p1, float2 p2, float2 p3)
            {
                float inTri1 = step(0.0, sign2D(p, p0, p1)) *
                               step(0.0, sign2D(p, p1, p3)) *
                               step(0.0, sign2D(p, p3, p0));

                float inTri2 = step(0.0, sign2D(p, p0, p3)) *
                               step(0.0, sign2D(p, p3, p2)) *
                               step(0.0, sign2D(p, p2, p0));

                return inTri1 + inTri2;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                float2 uv = i.uv;

                float2 p0 = _QuadP0.xy;
                float2 p1 = _QuadP1.xy;
                float2 p2 = _QuadP2.xy;
                float2 p3 = _QuadP3.xy;

                float inside = PointInQuad(uv, p0, p1, p2, p3);

                fixed4 colInside = tex2D(_MainTex, uv);
                fixed4 colOutside = fixed4(0,0,0,1);

                // inside > 0 表示点在四边形内
                return lerp(colOutside, colInside, saturate(inside));
            }
            ENDCG
        }
    }
}