smart-bow-infrared/Assets/ThirdAssets/JCUnityLib/UI/ValidateJigsaw/ValidateJigsaw.shader

//验证码拖拽
Shader "JC/UI/ValidateJigsaw"
{
    Properties
    {
        [PerRendererData] _MainTex("Sprite Texture", 2D) = "white" {}
        _Color("Tint", Color) = (1,1,1,1)
 
        _StencilComp("Stencil Comparison", Float) = 8
        _Stencil("Stencil ID", Float) = 0
        _StencilOp("Stencil Operation", Float) = 0
        _StencilWriteMask("Stencil Write Mask", Float) = 255
        _StencilReadMask("Stencil Read Mask", Float) = 255
 
        _ColorMask("Color Mask", Float) = 15
 
        [Toggle(UNITY_UI_ALPHACLIP)] _UseUIAlphaClip("Use Alpha Clip", Float) = 0
 
        _NodeWidth("Node Width", Float) = 100
        _NodeHeight("Node Height", Float) = 100
        _GapColor("Gap Color", Color) = (0,0,0,1)
        _GapBorderColor("Gap Border Color", Color) = (1,1,1,1)
        _GapBorderWidth("Gap Border Width", Float) = 0.5
        _GapSize("Gap Size", Float) = 20
        _OriginalPosition("Original Position", Vector) = (40, 40, 0)
        _CurrentPosition("Current Position", Vector) = (10, 40, 0)
    }
 
    SubShader
    {
        Tags
        {
            "Queue" = "Transparent"
            "IgnoreProjector" = "True"
            "RenderType" = "Transparent"
            "PreviewType" = "Plane"
            "CanUseSpriteAtlas" = "True"
        }
 
        Stencil
        {
            Ref[_Stencil]
            Comp[_StencilComp]
            Pass[_StencilOp]
            ReadMask[_StencilReadMask]
            WriteMask[_StencilWriteMask]
        }
 
        Cull Off
        Lighting Off
        ZWrite Off
        ZTest[unity_GUIZTestMode]
        Blend SrcAlpha OneMinusSrcAlpha
        ColorMask[_ColorMask]
 
        Pass
        {
            CGPROGRAM
#pragma vertex vert
#pragma fragment frag
 
#include "UnityCG.cginc"
#include "UnityUI.cginc"
 
#pragma multi_compile __ UNITY_UI_ALPHACLIP
 
            struct appdata_t
            {
float4 vertex   :
                POSITION;
float4 color    :
                COLOR;
float2 texcoord :
                TEXCOORD0;
            };
 
            struct v2f
            {
float4 vertex   :
                SV_POSITION;
fixed4 color :
                COLOR;
half2 texcoord  :
                TEXCOORD0;
float4 worldPosition :
                TEXCOORD1;
            };
 
            fixed4 _Color;
            fixed4 _TextureSampleAdd;
            float4 _ClipRect;
 
            float _NodeWidth;
            float _NodeHeight;
            float4 _GapColor;
            float4 _GapBorderColor;
            float _GapBorderWidth;
            float _GapSize;
            float2 _OriginalPosition;
            float2 _CurrentPosition;

            float2 _GapMapPosition;
 
            float4 _MainTex_TexelSize;
 
            v2f vert(appdata_t IN)
            {
                v2f OUT;
                OUT.worldPosition = IN.vertex;
                OUT.vertex = UnityObjectToClipPos(OUT.worldPosition);
 
                OUT.texcoord = IN.texcoord;
 
#ifdef UNITY_HALF_TEXEL_OFFSET
                OUT.vertex.xy += (_ScreenParams.zw - 1.0)*float2(-1,1);
#endif
 
                OUT.color = IN.color * _Color;
                return OUT;
            }
 
            sampler2D _MainTex;
 
            fixed4 frag(v2f IN) : SV_Target
            {
                half4 color = (tex2D(_MainTex, IN.texcoord) + _TextureSampleAdd) * IN.color;
 
                color.a *= UnityGet2DClipping(IN.worldPosition.xy, _ClipRect);
 
#ifdef UNITY_UI_ALPHACLIP
                clip(color.a - 0.001);
#endif

                float w = _NodeWidth;
                float h = _NodeHeight;
                float gbw = _GapBorderWidth;
                float gs = _GapSize;
                float2 op = _OriginalPosition;
                float2 cp = _CurrentPosition;

                float x = IN.texcoord.x * w;
                float y = IN.texcoord.y * h;
                
                if (x >= op.x && x < op.x + gs && y >= op.y && y < op.y + gs)
                {
                    if (x - op.x < gbw || x - op.x > gs - gbw || y - op.y < gbw || y - op.y > gs - gbw) color.rgba = _GapBorderColor;
                    else color.rgba = _GapColor;
                }
                
                if (x >= cp.x && x < cp.x + gs && y >= cp.y && y < cp.y + gs) 
                {
                    if (x - cp.x < gbw || x - cp.x > gs - gbw || y - cp.y < gbw || y - cp.y > gs - gbw) color.rgba = _GapBorderColor;
                    else
                    {
                        _GapMapPosition.x = (x - cp.x + op.x) / w;
                        _GapMapPosition.y = (y - cp.y + op.y) / h;
                        float4 _GapMapColor = tex2D(_MainTex, _GapMapPosition);
                        color.rgba = _GapMapColor;
                    }
                }
                return color;
            }
            ENDCG
        }
    }
}